Listato 1. Gestisce i led di ogni cifra

//prima parte
class Cifra {
    private var leds:Object;
    private var colore_led:Color;
    private var colore_sfondo:Color;
    static var colore:String = "verde";
    private var colori:Object;
    private var leds_mc:MovieClip;
    private var sfondo_mc:MovieClip;
    
    //seconda parte
    function Cifra() {
        colori = new Object();
         colori.grigio = {leds_on:"0x1E1E1E", leds_off:"0xBBBBBB", sfondo:"0xCCCCCC"};
        colori.verde = {leds_on:"0x00FF00", leds_off:"0x003300", sfondo:"0x06280A"};
        colori.rosso = {leds_on:"0x1E1E1E", leds_off:"0xC45309", sfondo:"0xDC5E0A"};
        for (var x = 0; x<7; x++) {
          //assegna un oggetto colore ad ogni led
          this["colore_led"+x] = new Color(leds_mc["led"+x]);
        }
        colore_sfondo = new Color(sfondo_mc);
        colore_sfondo.setRGB(colori[colore].sfondo);
        inizializzaElementi();
    }
    
    //terza parte
    private function inizializzaElementi() {
        leds = new Object();
        leds["0"] = new Array(1, 1, 1, 0, 1, 1, 1);
        leds["1"] = new Array(0, 0, 1, 0, 0, 1, 0);
        leds["2"] = new Array(1, 0, 1, 1, 1, 0, 1);
        leds["3"] = new Array(1, 0, 1, 1, 0, 1, 1);
        leds["4"] = new Array(0, 1, 1, 1, 0, 1, 0);
        leds["5"] = new Array(1, 1, 0, 1, 0, 1, 1);
        leds["6"] = new Array(0, 1, 0, 1, 1, 1, 1);
        leds["7"] = new Array(1, 0, 1, 0, 0, 1, 0);
        leds["8"] = new Array(1, 1, 1, 1, 1, 1, 1);
        leds["9"] = new Array(1, 1, 1, 1, 0, 1, 0);
        leds["meno"] = new Array(0, 0, 0, 1, 0, 0, 0);
    }
    
    //quarta parte
    private function visualizzaNumero(numero:Number) {
        for (var x = 0; x<7; x++) {
            var acceso:Number = leds[numero][x];
            if (acceso == 1) {
                accendiLed(x);
            } else {
                spegniLed(x);
            }
        }
    }
    
    private function accendiLed(nLed:Number) {
        this["colore_led"+nLed].setRGB(colori[colore].leds_on);
    }
    private function spegniLed(nLed:Number) {
        this["colore_led"+nLed].setRGB(colori[colore].leds_off);
    }
}